/////////////////////////////////////////////////////////////////////////////
// texmap.osl - texture mapping shader
//
// Description:
//   Read a texture map and put the values into output parameters.
//   This shader is intended to be used as a layer with its outputs 
//   connected to inputs of a later shader in the group.  It neither
//   gathers light nor modifies C in any way.
//
// Parameters:
//   texturename - name of the texture file
//   blur - how much to blur the texture lookup
//   wrap - texture mode wrap override
//   firstchannel - first channel in the map to look up
//   alphachannel - channel to get alpha from, or 0 to not bother w/ alpha
//   s,t - texture coordinates (default to u,v)
//
// Outputs:
//   Cout - color texture lookup value
//   fout - first channel of texture lookup (useful for 1-channel tex)
//   aout - alpha of texture (if requested)
//
/////////////////////////////////////////////////////////////////////////////
// Copyright 2004 NVIDIA Corporation.  All Rights Reserved.
// 
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are
// met:
// 
// * Redistributions of source code must retain the above copyright
//   notice, this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright
//   notice, this list of conditions and the following disclaimer in the
//   documentation and/or other materials provided with the distribution.
// * Neither the name of NVIDIA nor the names of its contributors
//   may be used to endorse or promote products derived from this software
//   without specific prior written permission.
// 
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
// OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
// LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
// DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
// THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
// (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
//
// (This is the Modified BSD License)
/////////////////////////////////////////////////////////////////////////////



shader
texmap 
    [[ string description = "Layer for simple texture mapping",
       float layer = 1 ]]
(
    string texturename = ""
        [[  string description = "Texture map name (empty for no texture)",
            string UItype = "texture" ]],
    float blur = 0
        [[  string description = "Texture map blur",
            float UImin = 0, float UIsoftmax = 1,
            string UIenabler = "texturename" ]],
    string wrap = "default"
        [[  string description = "Texture map wrap mode",
            string UIenabler = "texturename" ]],
    float firstchannel = 0
        [[  string description = "Texture channel to start reading for Cout",
            string UItype = "int", float UImin = 0,
            string UIenabler = "texturename" ]],
    float alphachannel = 3
        [[  string description = "Texture channel to read for aout",
            string UItype = "int", float UImin = 0,
            string UIenabler = "texturename" ]],
    float s = u
        [[  string description = "s texture coordinate (defaults to u)",
            string UIenabler = "texturename" ]],
    float t = v
        [[  string description = "t texture coordinate (defaults to v)",
            string UIenabler = "texturename" ]],
    output color Cout = 0
        [[  string description = "Color (3 channel) output" ]],
    output float fout = 0
        [[  string description = "Float (1 channel) output" ]],
    output float aout = 1
        [[  string description = "Alpha output" ]]
  )
{
    if (texturename) {
        Cout = texture (texturename, s, t, "firstchannel", (int)firstchannel,
                        "blur", blur, "wrap", wrap);
        fout = Cout[0];
        if (alphachannel >= 0)
            aout = texture (texturename, s, t, "firstchannel", (int)alphachannel,
                            "blur", blur, "wrap", wrap, "fill", 1);
        else aout = fout;
    }
}
