/////////////////////////////////////////////////////////////////////////////
// stucco.osl - displacement shader for stucco
//
// Description:
//   displacement shader for stucco
//   
// Parameters:
//   Km - scales the overall amplitude
//   freq - scales the overall frequency
//   sharp - controls the sharpness of the pimples
//   Pref - if supplied, gives the reference pose
//   shadingspace - space in which the pattern is laid out
//   shadingfreq - overall scaling factor for the pattern
//
/////////////////////////////////////////////////////////////////////////////
// Copyright 2004 NVIDIA Corporation.  All Rights Reserved.
// 
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are
// met:
// 
// * Redistributions of source code must retain the above copyright
//   notice, this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright
//   notice, this list of conditions and the following disclaimer in the
//   documentation and/or other materials provided with the distribution.
// * Neither the name of NVIDIA nor the names of its contributors
//   may be used to endorse or promote products derived from this software
//   without specific prior written permission.
// 
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
// OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
// LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
// DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
// THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
// (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
//
// (This is the Modified BSD License)
/////////////////////////////////////////////////////////////////////////////



#include "noises.h"


displacement
stucco
    [[ string description = "Stucco displacement, procedural" ]]
(
    float Km = 0.05
        [[  string description = "Overall amplitude" ]],
    float freq = 10
        [[  string description = "Frequency" ]],
    float sharp = 5
        [[  string description = "Sharpness",
            float UImin = 0 ]],
    point Pref = P
        [[  string description = "Reference pose (defaults to P)" ]],
    string shadingspace = "shader"
        [[  string description = "Shading space",
            string UItype = "coordsys" ]],
    float shadingfreq = 1
        [[  string description = "Shading frequency" ]]
  )
{
    point Pshad = freq * shadingfreq * transform (shadingspace, Pref);
    float dPshad = sqrt (area (Pshad));

    float amp = pow ((filteredsnoise(Pshad, dPshad)+1)*0.5, sharp);

    displace (shadingspace, Km*amp/shadingfreq);
}
