/////////////////////////////////////////////////////////////////////////////
// dispmap.osl - displacement along the normal either from an earlier 
//               layer or from a simple st texture lookup, or both.
//
// Parameters:
//   Km - scales the overall amplitude of displacement (default: 1)
//   offset - texture value that indicates neutral displacement.  E.g.,
//              0 means all displacement is positive (outwards along N), 
//              1 means all displacement in inwards (opposite of N),
//              0.5 means that vals < 0.5 dent in, vals > 0.5 puff out.
//   shadingspace - the space in which the displacement size is measured
//                  (default: "shader")
//   texturename - name of the texture file
//   disp - input of additional displacement from earlier layers
//   blur - how much to blur the texture lookup
//   wrap - texture mode wrap override
//   s,t - texture coordinates (default to u,v)
//
/////////////////////////////////////////////////////////////////////////////
// Copyright 2004 NVIDIA Corporation.  All Rights Reserved.
// 
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are
// met:
// 
// * Redistributions of source code must retain the above copyright
//   notice, this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright
//   notice, this list of conditions and the following disclaimer in the
//   documentation and/or other materials provided with the distribution.
// * Neither the name of NVIDIA nor the names of its contributors
//   may be used to endorse or promote products derived from this software
//   without specific prior written permission.
// 
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
// OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
// LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
// DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
// THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
// (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
//
// (This is the Modified BSD License)
/////////////////////////////////////////////////////////////////////////////



displacement
dispmap
    [[ string description = "Texture-mapped displacement" ]]
(
    float Km = 1
        [[  string description = "Amplitude of displacement" ]],
    float offset = 0 
        [[  string description = "Value indicating neutral displacement" ]],
    float disp = 0
        [[  string description = "Displacement input from earlier layers" ]],
    string shadingspace = "shader"
        [[  string description = "Space in which Km is measured",
            string UItype = "coordsys" ]],
    string texturename = ""
        [[  string description = "Texture map name (empty for no texture)",
            string UItype = "texture" ]],
    float blur = 0
        [[  string description = "Texture map blur",
            float UImin = 0, float UIsoftmax = 1,
            string UIenabler = "texturename" ]],
    string wrap = "default"
        [[  string description = "Texture map wrap mode",
            string UIenabler = "texturename" ]],
    float s = u
        [[  string description = "s texture coordinate (defaults to u)",
            string UIenabler = "texturename" ]],
    float t = v
        [[  string description = "t texure coordinate (defaults to v)",
            string UIenabler = "texturename"]]
  )
{
    float d = disp - offset;
    if (texturename) {
        d += texture (texturename, s, t, "blur", blur, "wrap", wrap);
    }
    displace (shadingspace, Km*d);
}
