/////////////////////////////////////////////////////////////////////////////
// screen.osl - make a metal screen
//
// Description:
//   Makes a surface that looks like a metal screen.  Strips run
//   parallel to lines of s and t.  You can adjust the Ka, Kd, Ks, etc.
//   to change the material appearance.
// 
// Parameters:
//   Ka, Kd, Ks, roughness, specularcolor - work just like the plastic shader
//   frequency - how many cycles of screen in st space
//   density - how much of each cycle is opaque?
//   s,t - texture coordinates (default to u,v)
//
/////////////////////////////////////////////////////////////////////////////
// Copyright 2004 NVIDIA Corporation.  All Rights Reserved.
// 
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are
// met:
// 
// * Redistributions of source code must retain the above copyright
//   notice, this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright
//   notice, this list of conditions and the following disclaimer in the
//   documentation and/or other materials provided with the distribution.
// * Neither the name of NVIDIA nor the names of its contributors
//   may be used to endorse or promote products derived from this software
//   without specific prior written permission.
// 
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
// OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
// LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
// DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
// THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
// (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
//
// (This is the Modified BSD License)
/////////////////////////////////////////////////////////////////////////////


#include "patterns.h"


surface
screen
    [[ string description = "Strips forming a screen" ]]
(
    float Ka = 1
        [[  string description = "Ambient scaling",
            float UImin = 0, float UIsoftmax = 1 ]],
    float Kd = 0.75
        [[  string description = "Diffuse scaling",
            float UImin = 0, float UIsoftmax = 1 ]],
    float Ks = 0.4
        [[  string description = "Specular scaling",
            float UImin = 0, float UIsoftmax = 1 ]],
    float roughness = 0.1
        [[  string description = "Surface roughness (specular highlight size)",
            float UImin = 0, float UImax = 1,
            string UIenabler = "Ks" ]],
    color specularcolor = 1
        [[  string description = "Specular highlight color",
            string UIenabler = "Ks" ]],

    float sdensity = 0.25
        [[  string description = "s strip density",
            float UImin = 0, float UImax = 1,
            string UIgroupbegin = "strips" ]],
    float tdensity = 0.25
        [[  string description = "t strip density",
            float UImin = 0, float UImax = 1 ]],
    float sfreq = 10
        [[  string description = "s strip frequency",
            float UImin = 0 ]],
    float tfreq = 10
        [[  string description = "t strip frequency",
            float UImin = 0, string UIgroupend = "strips" ]],

    float s = u
        [[  string description = "s texture coordinate (defaults to u)" ]],
    float t = v
        [[  string description = "t texure coordinate (defaults to v)" ]]
  )
{
    float ss = sfreq * s;
    float tt = tfreq * t;
    float swidth = filterwidth(ss);
    float twidth = filterwidth(tt);
    float d = 1 - (1 - filteredpulsetrain (1-sdensity, 1, ss, swidth)) *
                  (1 - filteredpulsetrain (1-tdensity, 1, tt, twidth));

    opacity *= d;
    if (d > 0) {
        vector V = -normalize (I);
        normal Nf = faceforward (normalize(N), I);
	C = C * (Ka*ambient() + Kd*diffuse(Nf)) +
            specularcolor * Ks*specular(Nf,V,roughness);
    }
    C *= opacity;
}
