/////////////////////////////////////////////////////////////////////////////
// castucco.gsl - stucco displacement
//
// Description:
//   Displacement shader for stucco, the kind found all over the place
//   in California.
//   
// Parameters:
//   Km - scales the overall amplitude
//   freq - scales the overall frequency (higher freq is smaller, sharper
//          bumps)
//   octaves - number of octaves in the fBm
//   sharp - controls the sharpness of the pimples
//   trough, peak - defines the shape of the valleys and mesas
//
// Hints:
//   * For ordinary stucco, try sharp=5, freq=10, octaves=1
//   * For "California" stucco, try freq=1, sharp=1, trough=-.15, peak=.35,
//     octaves=3
//
/////////////////////////////////////////////////////////////////////////////
// Copyright 2004 NVIDIA Corporation.  All Rights Reserved.
// 
// Redistribution and use in source and binary forms, with or without
// modification, are permitted provided that the following conditions are
// met:
// 
// * Redistributions of source code must retain the above copyright
//   notice, this list of conditions and the following disclaimer.
// * Redistributions in binary form must reproduce the above copyright
//   notice, this list of conditions and the following disclaimer in the
//   documentation and/or other materials provided with the distribution.
// * Neither the name of NVIDIA nor the names of its contributors
//   may be used to endorse or promote products derived from this software
//   without specific prior written permission.
// 
// THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
// "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
// LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
// A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
// OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
// SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
// LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
// DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
// THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
// (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
// OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
//
// (This is the Modified BSD License)
/////////////////////////////////////////////////////////////////////////////



#include "noises.h"


displacement
castucco
(
    float Km = 0.05
        [[  string description = "Overall amplitude" ]],
    float freq = 1
        [[  string description = "Frequency" ]],
    float octaves = 3
        [[  string description = "Octaves of noise",
            string UItype = "int", float UImin = 1, float UIsoftmax = 8 ]],
    float sharp = 1
        [[  string description = "Sharpness",
            float UImin = 0 ]],
    float trough = 0.43
        [[  string description = "Noise trough height",
            float UImin = 0, float UImax = 1 ]],
    float peak = 0.67
        [[  string description = "Noise peak height",
            float UImin = 0, float UImax = 1 ]],
    point Pref = P
        [[  string description = "Reference pose (defaults to P)" ]],
    string shadingspace = "shader"
        [[  string description = "Shading space",
            string UItype = "coordsys" ]],
    float shadingfreq = 1
        [[  string description = "Shading frequency" ]]
  )
{
    point Pshad = freq * shadingfreq * transform (shadingspace, Pref);
    float dPshad = sqrt(area(Pshad));

    // Start with fBm
    float amp = fBm (Pshad, dPshad, octaves, 2, 0.6) / 2 + 0.5;

    // Sharpen it by raising it to a power
    amp = pow (amp, sharp);

    // Threshold it
    amp = smoothstep (trough, peak, amp);

    displace (shadingspace, Km*amp/shadingfreq);
}
